.text
	.code 32

	.globl _start
_start:
	.ascii	"SC"
	.byte	0x11
	.byte	1		// Number of memory card blocks (use "mcpad" tool for auto-adjust)

	// Title 32*2 Shift-JIS zero padded (use "ascii2sjis" tool to generate this file)
	.include "data/title.txt"
	.space	12

	.hword	1		// Number of File Viewer Mono Icon Frames
	.ascii	"MCX0"
	.byte	1		// Number of entries in Executable Mono Icon List
	.byte	0		// No Function Table
	.word	0
	.word	_progstart

IconPS:	.incbin	"data/psicon.bin"	// 16*word Palette + 16x16 4bits Icon
IconPK:	.incbin	"data/icon.bin"		// File Viewer Mono Icon 32x32

	.hword	1		// Number of Executable Mono Icon
	.hword	1		// Icon Anim Speed
	.word	IconPK		// Pointer to the same File Viewer Mono Icon

_progstart:
	b	main

//----------------------------------------
// Bios Calls

	.globl	SetCallbacks
SetCallbacks:
	swi	1
	mov	pc, lr

	.globl	SetCpuSpeed
SetCpuSpeed:
	swi	4
	mov	pc, lr

	.globl	PrepareExecute
PrepareExecute:
	swi	8
	mov	pc, lr

	.globl	DoExecute
DoExecute:
	swi	9

	.globl	SetComOnOff
SetComOnOff:
	swi	17
	mov	pc, lr

	.globl	GetDirIndex
GetDirIndex:
	swi	22
	mov	pc, lr

	.globl	IntIRQ
IntIRQ:
	stmdb	sp!,{r2-r3,lr}
	bl	IRQ_Handler
	ldmia	sp!,{r2-r3,pc}

	.globl	IntFIQ
IntFIQ:
	stmdb	sp!,{r2-r3,lr}
	bl	FIQ_Handler
	ldmia	sp!,{r2-r3,pc}


//----------------------------------------
// User Data
	.end